Video Assets for Mailchimp + Salesforce: Part 6 - Sync Campaign Member from Mailchimp

public class MCSubscriberActivityTriggerHandler{

  public void afterInsert(List<MC4SF__MC_Subscriber_Activity__c> newRecords) {

    Map<String,String> CampaignMemberStatusMap = new Map<String,String>();
    Map<String,CampaignMember> cmMCSAMap = new Map<String,CampaignMember>();
    Map<String,Id> ldctSubscriberMap = new Map<String,Id>();
    List<Id> contactIdsList = new List<Id>();
    List<Id> leadIdsList = new List<Id>();
    List<Id> campaignIdsList = new List<Id>();
    List<String> contactSubscriberList = new List<String>();
    Set<String> newCampaignMembersSet = new Set<String>();
    Set<String> existingCampaignMembersSet = new Set<String>();
    List<CampaignMember> CampaignMembersToUpdate = new List<CampaignMember>();
    List<CampaignMember> CampaignMembersToInsert = new List<CampaignMember>();

    //set up all the member status mappings
    CampaignMemberStatusMap.Put('open','Opened');
    CampaignMemberStatusMap.Put('click','Clicked');
    CampaignMemberStatusMap.Put('bounce','Bounced');
    CampaignMemberStatusMap.Put('unsub','Unsubscribed');
    CampaignMemberStatusMap.Put('sent','Sent');

    //Make a list of the subscribers and campaigns
    List<MC4SF__MC_Subscriber_Activity__c> subscriberActivityList = [Select Id,MC4SF__MC_Subscriber__c,MC4SF__MC_Campaign__c,MC4SF__MC_Campaign__r.Campaign__c,MC4SF__Action__c FROM MC4SF__MC_Subscriber_Activity__c WHERE Id IN :newRecords];
    for(MC4SF__MC_Subscriber_Activity__c mcsa:subscriberActivityList){
      if(mcsa.MC4SF__MC_Subscriber__c != NULL)
          contactSubscriberList.Add(mcsa.MC4SF__MC_Subscriber__c);
      if(mcsa.MC4SF__MC_Campaign__r.Campaign__c != NULL)
          campaignIdsList.Add(mcsa.MC4SF__MC_Campaign__r.Campaign__c);
    }

    //Create a contact list and map to the subscriber
    for(Contact ct: [Select Id,MC4SF__MC_Subscriber__c FROM Contact WHERE MC4SF__MC_Subscriber__c IN :contactSubscriberList]){
      ldctSubscriberMap.Put(ct.MC4SF__MC_Subscriber__c,ct.Id);
      contactIdsList.Add(ct.Id);
    }
    
    //Create a lead list and map to the subscriber
    for(Lead ld: [Select Id,MC4SF__MC_Subscriber__c FROM Lead WHERE MC4SF__MC_Subscriber__c IN :contactSubscriberList]){
      ldctSubscriberMap.Put(ld.MC4SF__MC_Subscriber__c,ld.Id);
      leadIdsList.Add(ld.Id);
    }

    //Create a map of campaignId and lead/contact Id combination to the campaign member
    for(CampaignMember cm: [Select Id,ContactId,LeadId,CampaignId,Status FROM CampaignMember WHERE (ContactId IN :contactIdsList OR LeadId IN :leadIdsList) AND CampaignId IN :campaignIdsList]){
        if(cm.ContactId != NULL)
            cmMCSAMap.Put(cm.CampaignId + '_' + cm.ContactId, cm);
        else if(cm.LeadId != NULL)
            cmMCSAMap.Put(cm.CampaignId + '_' + cm.LeadId, cm);
    }
    
    //Loop through each subscriber activity
    for(MC4SF__MC_Subscriber_Activity__c mcsa:subscriberActivityList){

      //Get the associated contact/lead
      if(ldctSubscriberMap.ContainsKey(mcsa.MC4SF__MC_Subscriber__c) && ldctSubscriberMap.Get(mcsa.MC4SF__MC_Subscriber__c) != NULL && mcsa.MC4SF__MC_Campaign__c != NULL && mcsa.MC4SF__MC_Campaign__r.Campaign__c != NULL){
        Id contactOrLeadId = ldctSubscriberMap.Get(mcsa.MC4SF__MC_Subscriber__c);

        //Check if contact belongs to campaign already, if so, update it's status
        if(cmMCSAMap.ContainsKey(mcsa.MC4SF__MC_Campaign__r.Campaign__c + '_' + contactOrLeadId) && cmMCSAMap.get(mcsa.MC4SF__MC_Campaign__r.Campaign__c + '_' + contactOrLeadId) != NULL){
          CampaignMember existingCM = cmMCSAMap.get(mcsa.MC4SF__MC_Campaign__r.Campaign__c + '_' + contactOrLeadId);
          //Update the campaign member only if the status conditions are met and this particular record is not being updated in the same transaction
          if((!(existingCM.Status == 'Clicked' && (mcsa.MC4SF__Action__c=='sent' || mcsa.MC4SF__Action__c=='open'))) &&
            (!existingCampaignMembersSet.Contains(mcsa.MC4SF__MC_Campaign__r.Campaign__c + '_' + contactOrLeadId))
          ){
            if(CampaignMemberStatusMap.ContainsKey(mcsa.MC4SF__Action__c) && CampaignMemberStatusMap.Get(mcsa.MC4SF__Action__c) != NULL)
            existingCM.Status = CampaignMemberStatusMap.Get(mcsa.MC4SF__Action__c);
            CampaignMembersToUpdate.Add(existingCM);
            existingCampaignMembersSet.Add(mcsa.MC4SF__MC_Campaign__r.Campaign__c + '_' + contactOrLeadId);
          }
        }
        //Else, add it to the campaign
        else{
          //Check if the record is already part of the current transaction
          if(!newCampaignMembersSet.Contains(mcsa.MC4SF__MC_Campaign__r.Campaign__c + '_' + contactOrLeadId)){
            CampaignMember newCM = new CampaignMember(CampaignId=mcsa.MC4SF__MC_Campaign__r.Campaign__c);
            if(contactOrLeadId != NULL && String.ValueOf(contactOrLeadId).startsWith('00Q'))
                newCM.LeadId=contactOrLeadId;
            else
                newCM.ContactId=contactOrLeadId;
            if(CampaignMemberStatusMap.ContainsKey(mcsa.MC4SF__Action__c) && CampaignMemberStatusMap.Get(mcsa.MC4SF__Action__c) != NULL)
              newCM.Status=CampaignMemberStatusMap.Get(mcsa.MC4SF__Action__c);
            CampaignMembersToInsert.Add(newCM);
            newCampaignMembersSet.Add(mcsa.MC4SF__MC_Campaign__r.Campaign__c + '_' + contactOrLeadId);
          }
        }
      }
    }

    if(CampaignMembersToUpdate.size() > 0)
      update CampaignMembersToUpdate;

    if(CampaignMembersToInsert.size() > 0)
      insert CampaignMembersToInsert;
  }
}